【Unity Shaders】Reflecting Your World —— Unity3D中的法线贴图和反射

1. 首先，我们需要一个Cubemap来产生反射效果。所以你可以使用前一节中的Cubemap，或者生成一个新的。这一节中，我们使用的如下所示（你可以在本书资源中找到它）：
   
   
2. 我们还需要一张法线贴图来产生基于法线的反射效果。
   
   
3. 最后，创建一个新的场景、一个球体、一个平面以及一个平行光。同时，还需要创建一个新的Shader和Material，命名为NormalMappedReflection。
   

1. 首先让我们添加新的properties，使得我们能够添加自己的Cubemap和法线贴图。这个步骤你应该非常熟悉了。向Properties块添加下列代码：
   

   	Properties {
   		_MainTint ("Diffuse Tint", Color) = (1,1,1,1)
   		_MainTex ("Base (RGB)", 2D) = "white" {}
   		_NormalMap ("Normal Map", 2D) = "bump" {}
   		_Cubemap ("Cubemap", CUBE) = ""{}
   		_ReflAmount ("Reflection Amount", Range(0,1)) = 0.5
   	}

2. 然后，我们需要在SubShader块声明这些properties，使得我们能够访问Properties块中的这些数据：
   

   		CGPROGRAM
   		#pragma surface surf Lambert
   
   		samplerCUBE _Cubemap;
   		sampler2D _MainTex;
   		sampler2D _NormalMap;
   		float4 _MainTint;
   		float _ReflAmount;

   
   
3. 然后，修改Input结构体。这是基于法线贴图的反射的精华所在。通过使用INTERNAL_DATA声明，我们可以访问经过法线贴图修改后的平面的法线信息：
   

   		struct Input {
   			float2 uv_MainTex;
   			float2 uv_NormalMap;
   			float3 worldRefl;
   			INTERNAL_DATA
   		};

   
   
4. 最后，我们需要修改surf函数，来得到最后的基于法线贴图的反射效果：
   

   		void surf (Input IN, inout SurfaceOutput o) {
   			half4 c = tex2D (_MainTex, IN.uv_MainTex);
   			
   			float3 normals = UnpackNormal(tex2D(_NormalMap, IN.uv_NormalMap)).rgb;
   			o.Normal = normals;
   			
   			o.Emission = texCUBE (_Cubemap, WorldReflectionVector (IN, o.Normal)).rgb * _ReflAmount;
   			o.Albedo = c.rgb * _MainTint;
   			o.Alpha = c.a;
   		}

Shader "Custom/NormalMappedReflection" {
	Properties {
		_MainTint ("Diffuse Tint", Color) = (1,1,1,1)
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_NormalMap ("Normal Map", 2D) = "bump" {}
		_Cubemap ("Cubemap", CUBE) = ""{}
		_ReflAmount ("Reflection Amount", Range(0,1)) = 0.5
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		CGPROGRAM
		#pragma surface surf Lambert

		samplerCUBE _Cubemap;
		sampler2D _MainTex;
		sampler2D _NormalMap;
		float4 _MainTint;
		float _ReflAmount;

		struct Input {
			float2 uv_MainTex;
			float2 uv_NormalMap;
			float3 worldRefl;
			INTERNAL_DATA
		};

		void surf (Input IN, inout SurfaceOutput o) {
			half4 c = tex2D (_MainTex, IN.uv_MainTex);
			
			float3 normals = UnpackNormal(tex2D(_NormalMap, IN.uv_NormalMap)).rgb;
			o.Normal = normals;
			
			o.Emission = texCUBE (_Cubemap, WorldReflectionVector (IN, o.Normal)).rgb * _ReflAmount;
			o.Albedo = c.rgb * _MainTint;
			o.Alpha = c.a;
		}
		ENDCG
	} 
	FallBack "Diffuse"
}

			float3 normals = UnpackNormal(tex2D(_NormalMap, IN.uv_NormalMap)).rgb;
			o.Normal = normals;